Given/when expression

Given/when in Perl 5.10 is great (and will be even greater in Perl 6, for example we can remove many of the now-required parentheses). But it is very statement-oriented. Sometimes I miss CASE expressions a la SQL:

SELECT store_name, CASE store_name
  WHEN 'Los Angeles' THEN sales*2
  WHEN 'San Diego' THEN sales*1.5
  ELSE sales
  END AS new_sales
FROM store;

So, how do you do given/when expressions in Perl? I can think of a couple alternatives, but none is very appealing. Do you a have better one?

my @store = (
    {store_name=>'Los Angeles', sales=>100_000},
    {store_name=>'San Diego', sales=>100_000},
    {store_name=>'Anaheim', sales=>100_000}
);

1. do {} + if/elsif (con: needs do{}, needs explicit assignment to $_, no implicit smart matching)

for my $s (@store) {
    printf "%s %d %d\n", $s->{store_name}, $s->{sales}, do {
        local $_ = $s->{store_name};
        if (/Angel/) { $s->{sales}*2 }
        elsif ($_ eq 'San Diego') { $s->{sales}*1.5 }
        else { $s->{sales} }
    };
}

2. do {} + given/when (con: needs do{}, needs $tmp assignments)

for my $s (@store) {
    printf "%s %d %d\n", $s->{store_name}, $s->{sales}, do {
        my $tmp;
        given($s->{store_name}) {
            when (/Angel/) { $tmp = $s->{sales}*2 }
            when ('San Diego') { $tmp = $s->{sales}*1.5 }
            default { $tmp = $s->{sales} }
        }
        $tmp
    };
}

3. sub {} + given/when (con: needs sub{}, slower perhaps?, needs explicit return's)

for my $s (@store) {
    printf "%s %d %d\n", $s->{store_name}, $s->{sales}, sub {
        given ($s->{store_name}) {
            when (/Angel/) { return $s->{sales}*2 }
            when ('San Diego') { return $s->{sales}*1.5 }
            default { return $s->{sales} }
        }
    }->();
}